LBB 6 System Gen Perplexation

[jawillroy]

And now I have a stupid trig & excel question.

I have an orbital distance for Ismir - 2.5 million km.
I gave an orbital distance for Adip - about 3.5 million km.

Thanks to Aramis, I can get their orbital position in degrees - should that not give me an angle?

That being the case, I should be able to calculate the distance between Ismir and Adip - but my excel skills are defeated, I keep getting wacky numbers and I don't know enough to know what I'm doing wrong.

What should I be doing?

 

[aramis]

Find the XY coords for each...

Ax=Ad*Sin(Ap)
Ay=Ad*Cos(Ap)
Bx=Bd*Sin(Bp)
By=Bd*Cos(Bp)

when _d = distance of _, and _p = position In degrees or rads or grads, as needed

Then the hypotenuse of the right triangle on the grid...

Dab = √((Ax-Bx)²+(Ay-By)²)

 

[jawillroy]

I'm quite sure I don't understand. I'm not starting from the point of having an XY grid to plot on: everything's measured off a central point (center being a star, or a planet) and sides a and b formed by the lines between two bodies orbiting that star or planet.

I'm not getting something, I think.

 

[aramis]

I'm quite sure I don't understand. I'm not starting from the point of having an XY grid to plot on: everything's measured off a central point (center being a star, or a planet) and sides a and b formed by the lines between two bodies orbiting that star or planet.

I'm not getting something, I think.

Working in polar coordinates is harder to do the math.

This is a case of "Trust me".

The first step is to convert the polar coordinates (degree and distance) into rectangular ones (The star will be at 0,0, FYI). this gives you an XY coordinate set.

That's the sin and cos functions.

Date§	Period	Offset	distance	Current degrees	current X	Current Y
32	245	36	5	=round(360*mod(($a$2+c2),b2)/b2,1)	=round(d2*sin(radians(e2)),2)	=round(d2*cos(radians(e2)),2)
	452	400	15	=round(360*mod(($a$2+c3),b3)/b3,1)	=round(d3*sin(radians(e3)),2)	=round(d3*cos(radians(e3)),2)

This version adds the xy coords. Which gives us a right triangle to work with to find the direct distance.
The sides we know are the difference of X's, and the difference of Y's.
Dx=|Ax-Bx|
Dy=|Ay-By|
The missing hypotenuse is h=((Dx^2)+(Dy^2))^0.5

We can do this in excel/numbers easily. On a new table...

Ax	Ay	Bx	By	Distance
4	-5	-2	7	=round(sqrt(((a2-c2)^2)+((b2-d2)^2)),2)

 

[jawillroy]

I'm going to try that - thank you!

 

[aramis]

One more note: whatever unit you use for distance in the orbit, that's also the unit that will result from the calculations.

 

[aramis]

I've been going completely insane with this very question, and choosing the absolute other route. I want to know where everything important in a particular system IS, how fast it's moving, and how the important distances change. (I'm thinking of having a political situation hinge on orbital positions and want it to make sense.)

In practical terms I don't recommend it :eyeroll:

Using LBB6 and significant help from Aramis, I'm figuring out orbital periods, the whole nine. I'm hoping it'll be easy to adapt to other planetary systems once I've figured it out for the one. 'Cause this is haaaaard.

Well, FYI, in a multi star system, the (X,Y) coords are relative to their star, and so worlds of the companion star add their star's (X,Y) coords to their own for figuring where they are in relation to the primary.

So
Star A is 0,0
P A1 is at -1,0
P A2 is ar 2,0
P A3 is at 0,4
Star B is at 7,4
P B1 figured at 1,0 from B is overall at (7+1,4+0)=8,4
P B2 figured at 0,-2 from B is overall at (7+0,4-2)=7,2

You can use columnar trickery/jiggery-poo to calculate the distances automatically as a single sheet.

It involves using multiple header rows...

You put the links to the current X & Y locations into two header rows which you hide.
So, we'll move the first line of data down two rows. This may take a bit of time to update for a large or complex system.

We put the date into the header, and use the rest of col A for names...

Date§						X:	=F4	=F5	=F6	=F7
32						Y:	=G4	=G5	=G6	=G7
Name	Period	Offset	distance	Current degrees	current X	Current Y	=A4	=A5	=A6	=A7
Ayesh	245	36	5	=round(360*mod(($a$2+c4),b4)/b4,1)	=round(d4*sin(radians(e4)),2)	=round(d2*cos(radians(e2)),2)	=round(sqrt(((H$1-$F4)^2)+((H$2-$G4)^2)),2)
Besh	452	400	15	=round(360*mod(($a$2+c5),b5)/b5,1)	=round(d5*sin(radians(e5)),2)	=round(d5*cos(radians(e5)),2)
Gemel	452	400	15	=round(360*mod(($a$2+c6),b6)/b6,1)	=round(d6*sin(radians(e6)),2)	=round(d6*cos(radians(e6)),2)
Nut	452	400	15	=round(360*mod(($a$2+c7),b7)/b7,1)	=round(d7*sin(radians(e7)),2)	=round(d7*cos(radians(e6)),2)

You then use fill commands to fill down from H3 to the bottom right corner.

Really, it's not hard to do, but grasping the concept isn't always easy to do.

Sine and Cosine are simply the fractions of the distance to draw a point along a circle. There are three systems of measuring angles and arcs in common use: Degrees (360), gradians (400), or radians (2π); I used the conversion routines because you're using a spreadsheet. Some calculators wand degrees, some want radians
if you need to manually convert, radians = π * degrees/180

 

[jawillroy]

Slick.

Starting to get the hang of it - it'll be interesting to see how all this background will play out in the actual game!